DIAdemをActiveXオブジェクトとして制御

PDFをダウンロード

更新日2023-04-06
11分で読める

このサンプルでは、DIAdemをActiveXオブジェクトとして使用する方法と、DIAdemを別のアプリケーションからリモート制御する方法を示します。

メモ使用している安全設定に応じて、オペレーティングシステムはActiveX要素が安全でない可能性があることを警告します。サンプルを実行するには、コントロールを登録する必要があります。この警告は、HTMLページに自動化オブジェクトを埋め込むのにCreateObjectコマンドを使う場合に表示されます。

メモこのサンプルを開始するとサンプルファイルが読み込まれ、既存のデータとレイアウトは上書きされます。

メモ以下のスクリプトは、このヘルプページのHTMLコードに埋め込まれています。スクリプトはDIAdemをActiveXオブジェクトとして登録し、DIAdemのコマンドインターフェースを使用してコマンドを送信します。他のすべての埋め込まれたスクリプトは、HTMLフォームを評価するためのものです。

スクリプトをコピー

Dim oMyDIAdem, ProgramDrv
Set oMyDIAdem = new DIAdemAutomation

Call oMyDIAdem.LoadDiademDataSet(ProgramDrv & "examples\data\report_expl.tdm", True)
Call oMyDIAdem.LoadDiademLayout(ProgramDrv & "examples\documents\Expl_Report_2DAxis.TDR")
Set oMyDIAdem = Nothing

Class DIAdemAutomation
Dim oDIAdem, DIAdemApp
  Private Sub Class_Initialize()
    Set oDIAdem = Nothing
    Call ConnectToDIAdem
    Call oDIAdem.VariantVarget("Application",DIAdemApp)
    Call oDIAdem.VariantVarget("ProgramDrv",ProgramDrv)
  End Sub

  '================================================================
  Private Sub Class_Terminate()
    Set oDIAdem = Nothing
  End Sub

  
  '================================================================ 
  Function DIAdem_Exec(DIAdemCommand)
      DIAdem_exec = False
      If ConnectToDIAdem Then
          If oDIAdem.CmdExecuteSync(DIAdemCommand) = 1 Then DIAdem_exec = True
      End If
  End Function
  '================================================================
  Sub LoadDiademLayout(LayOut)
     Call DIAdemApp.Report.LoadLayout(LayOut)
     Call DIAdem_exec("WndOpen(""Report"")")
     Call DIAdemApp.Report.Refresh
  End Sub

  '================================================================
  Sub ExportPDF(PDFName)
    Call DIAdemApp.Report.Sheets.ExportToPDF(PDFName)
  End Sub
  
  '================================================================
  Function LoadDiademDataSet(DataSet, clear)
    If clear Then
      Call DIAdemApp.Data.Root.Clear
    End if
    Dim MyCommand : MyCommand = "DataFileLoad(""" & DataSet & """)"
    LoadDiademDataSet = DIAdem_exec(MyCommand)
  End Function
  
  '================================================================
  Private Function ConnectToDIAdem
    Dim nValueT, iWait
    If NOT oDIAdem Is Nothing Then
      ConnectToDIAdem = True
      Exit Function
    End If  
    ConnectToDIAdem = False
      On Error Resume Next
      Set oDIAdem = CreateObject("DIAdem.TOCommand")
      If Err.Number > 0 then
        Set oDIAdem = Nothing
        Err.Clear
      Else
        iWait = 0 
        Do 
          iWait = iWait + 1
          If iWait >=1000 Then
            Exit Function
          End If
        Loop Until Not oDIAdem.bInterfaceLocked    
        ' Suppress all messages
        oDIAdem.bNoMsgDisplay = true
        oDIAdem.bNoInfoDisplay = true
        oDIAdem.bNoErrorDisplay = true
        oDIAdem.bNoWarningDisplay = true
        oDIAdem.bNoNoDialogDisplay = true
        ConnectToDIAdem = True
      End If
  End Function

End Class

oMyDIAdem = new DIAdemAutomation 
oMyDIAdem.LoadDiademDataSet(dd.ProgramDrv + "examples\\data\\report_expl.tdm", True) 
oMyDIAdem.LoadDiademLayout(dd.ProgramDrv + "examples\\documents\\Expl_Report_2DAxis.TDR") 
oMyDIAdem = None 
class DIAdemAutomation: 
    def _Class_Initialize(self): 
        oDIAdem = None 
        ConnectToDIAdem 
        oDIAdem.VariantVarget("Application",DIAdemApp) 
        oDIAdem.VariantVarget("ProgramDrv",dd.ProgramDrv) 
#================================================================
    def _Class_Terminate(self): 
        oDIAdem = None 
#================================================================ 
    def DIAdem_Exec(self, DIAdemCommand): 
        DIAdem_exec = False 
        if ConnectToDIAdem : 
            if oDIAdem.CmdExecuteSync(DIAdemCommand) == 1 : DIAdem_exec = True 
            return DIAdem_Exec
#================================================================
        def LoadDiademLayout(self, LayOut): 
            DIAdemApp.Report.LoadLayout(LayOut) 
            DIAdem_exec("WndOpen(""Report"")") 
            DIAdemApp.Report.Refresh() 
#================================================================
        def ExportPDF(self, PDFName): 
            DIAdemApp.Report.Sheets.ExportToPDF(PDFName) 
#================================================================
        def LoadDiademDataSet(self, DataSet, clear): 
            if clear : 
                DIAdemApp.Data.Root.Clear() 
            MyCommand = "DataFileLoad(""" + DataSet + """)" 
            LoadDiademData= DIAdem_exec(MyCommand) 
            return LoadDiademDataSet
#================================================================
        def _ConnectToDIAdem(self): 
            if not oDIAdem is None : 
                ConnectToDIAdem = True 
                Exit Function 
            ConnectToDIAdem = False 
            On Error Resume Next 
            oDIAdem = win32com.client.dis-patch("DIAdem.TOCommand") 
            if Err.Number > 0 : 
                oDIAdem = None 
                Err.Clear() 
            else: 
                iWait = 0 
                while True: 
                    iWait = iWait + 1 
                    if iWait >==1000 : 
                        Exit Function 
                if not oDIAdem.bInterfaceLocked:
                        break 
# Suppress all messages
                oDIAdem.bNoMsgDisplay = True 
                oDIAdem.bNoInfoDisplay = True 
                oDIAdem.bNoErrorDisplay = True 
                oDIAdem.bNoWarningDisplay = True 
                oDIAdem.bNoNoDialogDisplay = True 
                ConnectToDIAdem = True 
            return ConnectToDIAdem

DIAdemヘルプ

目次

DIAdemをActiveXオブジェクトとして制御